home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / bowling.arc / RECORDD.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1985-07-12  |  3.9 KB  |  102 lines
  1. 10  REM DISPLAY TEAM AND BOWLER RECORD SHEETS      (RECORDD)
  2. 12  REM Developed by William W. Klaproth,  Moraga Ca.  94556    September 1982
  3. 20  REM MASTER FILE DESCRIPTIONS FOR ALL BOWLING PROGRAMS
  4. 30  OPEN "B:TEAMS.HDR" AS #1 LEN = 64
  5. 40  FIELD #1, 2 AS TM$, 30 AS NAM$, 2 AS RCNT$, 2 AS GAM$, 4 AS PINS$, 2 AS AVG$, 2 AS HIG$, 2 AS HIS$, 4 AS PTSW$, 4 AS PTSL$, 2 AS B1ID$, 2 AS B2ID$, 2 AS B3ID$, 2 AS B4ID$, 2 AS B5ID$
  6. 50  FIELD #1, 2 AS HDRID$, 30 AS LEAGUE$, 2 AS WEEKS$, 2 AS TEAMS$, 4 AS FILLER$, 2 AS BWLPERTM$, 2 AS NXTID$, 2 AS HCPBASE$, 4 AS HCPPCNT$
  7. 60  OPEN "B:BOWLERS.HDR" AS #2 LEN = 64
  8. 70  FIELD #2, 2 AS BBO$, 30 AS BNAM$, 2 AS BRCNT$, 2 AS BGAM$, 4 AS BPINS$, 2 AS BAVG$, 2 AS BHIG$, 2 AS BHIS$, 2 AS BHCP$, 2 AS BHIGH$, 2 AS BHISH$, 2 AS BTM$,2 AS GAM2$, 2 AS SER5$, 2 AS SER6$,2 AS CURSER$,2 AS AVGLSTYR$
  9. 80  OPEN "B:TEAM.DET" AS #3 LEN = 16
  10. 90  FIELD #3,2 AS DTM$, 2 AS TMO$, 2 AS TDAY$, 2 AS TG1$, 2 AS TG2$, 2 AS TG3$, 2 AS TSER$, 2 AS DPTSW$
  11. 100  OPEN "B:BOWLER.DET" AS #4 LEN = 16
  12. 110  FIELD #4,2 AS DBO$, 2 AS BMO$, 2 AS BDAY$, 2 AS BG1$, 2 AS BG2$, 2 AS BG3$, 2 AS BSER$
  13. 120  REM OPEN "B:HISCORES.DET" AS #5 LEN = 16
  14. 130  REM FIELD #5, 2 AS HBNO$, 2 AS HG1$, 2 AS HG2$, 2 AS HG3$, 2 AS HSER$, 1 AS HFLG1$, 1 AS HFLG2$, 1 AS HFLG3$, 1 AS HFLGS$
  15. 140  CLS
  16. 150  PRINT "TEAM AND BOWLER RECORD SHEET DISPLAY PROGRAM"
  17. 160  PRINT " "
  18. 170  INPUT "ENTER DESIRED PRINT OPTION: T=TEAMS; B=BOWLERS; Q=QUIT :",OP$
  19. 180  IF OP$ = "T" OR OP$ = "t" GOTO 280
  20. 190  IF OP$ = "B" OR OP$ = "b" GOTO 230
  21. 200  IF OP$ = "Q" OR OP$ = "q" GOTO 330
  22. 210  PRINT "INVALID OPTION ENTERED"
  23. 220  GOTO 170
  24. 230  INPUT "ENTER DESIRED BOWLER NUMBER (999 TO QUIT):",B%
  25. 240  CLS
  26. 250  IF B% = 999 GOTO 170
  27. 260  GOSUB 370
  28. 270  GOTO 230
  29. 280  INPUT "ENTER DESIRED TEAM NUMBER (99 TO QUIT):",T%
  30. 290  CLS
  31. 300  IF T% = 99 GOTO 170
  32. 310  GOSUB 730
  33. 320  GOTO 280
  34. 330  PRINT "Returning to MENU"
  35. 340  CLOSE
  36. 350  RUN "A:MENU"
  37. 360  REM SUBROUTINE TO PRINT BOWLER RECORD SHEETS
  38. 370  PRINT "                    BOWLER RECORD SHEET            ";DATE$
  39. 380  PRINT " "
  40. 390  GET #2,B%
  41. 400  PRINT BNAM$;"     HIGAM  HISER  HHGAM  HHSER"
  42. 410  PRINT SPC(33);
  43. 420  PRINT USING "   ####";CVI(BHIG$),CVI(BHIS$),CVI(BHIGH$),CVI(BHISH$)
  44. 430  PRINT " "
  45. 440  PRINT "                          GRAND"
  46. 450  PRINT " DATE GAM1 GAM2 GAM3  TOT TOTAL GAM  AVG"
  47. 460  PRINT "----- ---- ---- ----  --- ----- ---  ---"
  48. 470  GAM% = 0:PINS = 0
  49. 480  FOR TREC% = 1 TO CVI(BRCNT$)
  50. 490  REM RANDOMIZING ROUTINE FOR BOWLER DETAIL ADDRESSES
  51. 500  X = B% / 2: X% = CINT(X): Y% = X% * 2
  52. 510  WREC% = TREC%
  53. 520  IF Y% = B% THEN WREC% = TREC% + 50
  54. 530  BDET% = X% * 100 + WREC% - 100
  55. 540  REM END OF RANDOMIZING ROUTINE
  56. 550  GET #4,BDET%
  57. 560  G% = 3   'CALCULATE NUMBER OF GAMES BOWLED
  58. 570  IF CVI(BG1$) = 0 THEN G% = G% -1
  59. 580  IF CVI(BG2$) = 0 THEN G% = G% -1
  60. 590  IF CVI(BG3$) = 0 THEN G% = G% -1
  61. 600  GAM% = GAM% + G%
  62. 610  PINS = PINS + CVI(BSER$)
  63. 620  AVG = PINS / GAM%
  64. 630  AVG% = INT(AVG)
  65. 640  PRINT USING "##";CVI(BMO$);
  66. 650  PRINT "-";
  67. 660  PRINT USING "## ";CVI(BDAY$);
  68. 670  PRINT USING "#### ";CVI(BG1$),CVI(BG2$),CVI(BG3$),CVI(BSER$);
  69. 680  PRINT USING "##### ";PINS;
  70. 690  PRINT USING "###  ";GAM%,AVG%
  71. 700  NEXT TREC%
  72. 710  RETURN
  73. 720  REM SUBROUTINE TO PRINT TEAM RECORD SHEETS
  74. 730  PRINT "                     TEAM RECORD SHEET             ";DATE$
  75. 740  PRINT " "
  76. 750  GET #1,T% + 1
  77. 760  PRINT NAM$;"HI GAME:";CVI(HIG$);"   HI SERIES:";CVI(HIS$)
  78. 770  PRINT " "
  79. 780  PRINT "                  SEASON                      GRAND"
  80. 790  PRINT " DATE  WON LOST  WON LOST GAM1 GAM2 GAM3  TOT TOTAL  GAM  AVG"
  81. 800  PRINT "-----  --- ----  --- ---- ---- ---- ----  --- -----  ---  ---"
  82. 810  GAM%=0: PINS=0: TGW=0: TGL=0
  83. 820  FOR TREC% = 1 TO CVI(RCNT$)
  84. 830  REM RANDOMIZING ROUTINE FOR TEAM DETAIL ADDRESSES
  85. 840  X = T% / 2: X% = CINT(X): Y% = X% * 2
  86. 850  TWREC% = TREC%
  87. 860  IF Y% = T% THEN TWREC% = TREC% + 50
  88. 870  TDET% = X% * 100 + TWREC% - 100
  89. 880  REM END OF RANDOMIZING ROUTINE
  90. 890  GET #3,TDET%
  91. 900  PRINT USING "##";CVI(TMO$);
  92. 910  PRINT "-";
  93. 920  PRINT USING "##";CVI(TDAY$);
  94. 930  GW=CVI(DPTSW$)/10: GL=4-GW: TGW=TGW+GW: TGL=TGL+GL
  95. 940  PRINT USING " ##.#";GW,GL,TGW,TGL;
  96. 950  PRINT USING " ####";CVI(TG1$),CVI(TG2$),CVI(TG3$),CVI(TSER$);
  97. 960  PINS=PINS+CVI(TSER$): GAM%=GAM%+3: AVG=PINS/GAM%: AVG%=INT(AVG)
  98. 970  PRINT USING " #####";PINS;
  99. 980  PRINT USING " ####";GAM%,AVG%
  100. 990  NEXT TREC%
  101. 1000  RETURN
  102.